TryParse()

OutputVar := MfEnum.TryParse(value, outEnum)
OutputVar := MfEnum.TryParse(value, outEnum, ignoreCase)

MfEnum.TryParse(value, outEnum)

Converts the string representation of the name or numeric value of one or more enumerated constants to an equivalent enumerated object. The return value indicates whether the conversion succeeded. This method is case-insensitive.

MfEnum.TryParse(value, outEnum, ignoreCase)

Converts the string representation of the name or numeric value of one or more enumerated constants to an equivalent enumerated object. A parameter specifies whether the operation is case-sensitive. The return value indicates whether the conversion succeeded.

Parameters

value

The string representation of the enumeration name or underlying value to convert.

outEnum

When this method returns true, outEnum value contains the representation of value parameter. outEnum must be an instance of the derived MfEnum that is beign parsed.

ignoreCase

true to ignore case; false to consider case.

Returns

Returns true if the value parameter was converted successfully; otherwise, false.

Remarks

Static Method

Related

Parse(), ParseItem(), TryParseItem()

Example

; create an instance of RegOptEnum for the TryParse
outEnum := new RegOptEnum()

mykey := Mfunc.IniRead("C:\Temp\myfile.ini", "REG", "KEYS_REG_DWORD")
; mykey is expected to contain value of KeysRegDword

; TryParse is boolean so will use if statement.
if (MfEnum.TryParse(mykey, outEnum))
{
   MsgBox,,SUCCESS, % "outEnum value is:" . outEnum.Value . " and name is:" . outEnum.ToString()
} else {
   MsgBox Failed
}

; create a new enumeration class by inheriting/extending the MfEnum
class RegOptEnum extends MfEnum
{
   static m_Instance := MfNull.Null
   __New(args*)
   {
       if (this.base.__Class != "RegOptEnum")
       {
           throw new MfNotSupportedException(MfEnvironment.Instance.GetResourceString("NotSupportedException_Sealed_Class"
               ,"RegOptEnum"))
       }
       base.__New(args*)
       ; set MfObject m_isInherited flag for testing if Class is inherited/extended if needed
       ; This could be set to false as this class cannot be inherited/extended as set in this constructor above
       ; but will do it the standard way.
       this.m_isInherited := this.__Class != "RegOptEnum"
   }
       
   ; override the base AddEnums, this is required
   ; add all the enum values for your enum here
   AddEnums() {
       this.AddEnumValue("RegDword", 0)
       this.AddEnumValue("KeysRegDword", 1)
       this.AddEnumValue("RegSz", 2)
       this.AddEnumValue("KeysRegSz", 3)
       this.AddEnumValue("RegBinary", 4)
       this.AddEnumValue("KeysRegBinary", 5)
       this.AddEnumValue("AutoresponseRegSz", 6)
       this.AddEnumValue("KeysAutoresponseRegSz", 7)
       this.AddEnumValue("AutoupdateRegSz", 8)
       this.AddEnumValue("KeysAutoupdateRegSz", 9)
       this.AddEnumValue("AutoupdateRegBinary", 10)
       this.AddEnumValue("KeysAutoupdateRegBinary", 11)
       this.AddEnumValue("KeypathsRegSz", 12)
       this.AddEnumValue("KeysKeypathsRegSz", 13)
       this.AddEnumValue("KeypathsRegDword", 14)
       this.AddEnumValue("KeysKeypathsRegDword", 15)
       this.AddEnumValue("WindowplacementRegBinary", 16)
       this.AddEnumValue("KeysWindowplacementRegBinary", 17)
   }

   ; override the base DestroyInstance, this is required
   DestroyInstance() {
       RegOptEnum.m_Instance := Null        
   }

   ; override the base GetInstance, this is required
   ; Get a static default instance, create if not exist yet
   GetInstance() {
       if (MfNull.IsNull(RegOptEnum.m_Instance))
       {
           RegOptEnum.m_Instance := new RegOptEnum(0)
       }
       return RegOptEnum.m_Instance
   }
}