Value

Overrides MfPrimitive.Value

Gets or sets the value associated with the this instance of MfFloat

OutputVar := instance.Value
instance.Value := Value

value

Value is a float value and can be var or object

Sets

Set the Value of the instance. Can be var or any object that matches IsNumber.

Gets

Setting float Value as var

Throws

Throws MfNotSupportedException if when trying to set if Readonly is true.
Throws MfInvalidCastException if unable to set property to value.
Throws MfNotSupportedException on set if Readonly is true.

Remarks

The Value property can be set to any valid number without first setting the SetFormat() values of AutoHotkey.
Also getting the Value property does not require setting the SetFormat values of AutoHotkey.
However setting the Value property using the +=,-=, ++, --, *=, /= operators requires setting the SetFormat values of AutoHotkey before using these operators.
To avoid issues with having to SetFormat ust the Add(), Subtract(), Divide() and Multiply() methods.

Example

; construct a new instance of MfFloat
; set is value to 1.00000003
; Format of "0.9" that is TotalWidth will be set to 0 ( no padding )
; and DecimalPlaces will be set to 9
mffA := new MfFloat(1.00000003, , , "0.9")

MsgBox % mffA.Value ; displays 1.000000030

; create a new MfFloat and set is values
; to the value and format of mmfA
mffB := new MfFloat(mffA,,,mffA.Format)
MsgBox % mffB.Value ; displays 1.000000030

MsgBox % mffA.GreaterThen(mffB)?"True":"False" ; displays False
MsgBox % mffA.LessThen(mffB)?"True":"False"    ; displays False
MsgBox % mffA.Equals(mffB)?"True":"False"      ; displays True

mffA.Add(0.001)
MsgBox % mffA.Value ; displays 1.001000030

MsgBox % mffA.GreaterThen(mffB)?"True":"False" ; displays True
MsgBox % mffA.LessThen(mffB)?"True":"False"    ; displays False
MsgBox % mffA.Equals(mffB)?"True":"False"      ; displays False

mffB.Value += 1.2 ; this is an error because SetFromat was not set first
MsgBox % mffB.Value ; displays 2.200000000 but expected 2.200000030
; this error has to do with how AutoHotkey formats floats.
; we have two work arounds

; The first work around
mffB.Value := 1.00000003 ; Reset the value to our original
mffB.Add(1.2) ; this is the easy fix
MsgBox % mffB.Value ; displays 2.200000030

; The second work around is to use setFormat
mffB.Value := 1.00000003 ; Reset the value to our original
; use the format that our MfFloat instance is using
wasformat := Mfunc.SetFormat(MfSetFormatNumberType.Instance.FloatFast, mffB.Format)
mffB.Value += 1.2 ; this now is correct because format is set
Mfunc.SetFormat(MfSetFormatNumberType.Instance.FloatFast, wasformat) ; reset the format back to where it was
MsgBox % mffB.Value ; displays 2.200000030