Add()

Overrides MfListBase.Add()

OutputVar := instance.Add(obj)

Add(obj)

Adds an object to the end of the MfGenericList.

Parameters

obj

The Object to add in the MfGenericList

Returns

Var containing Integer of the zero-based index at which the obj has been added.

Throws

Throws MfNullReferenceException if called as a static method.
Throws MfNotSupportedException if MfGenericList is read-only or Fixed size
Throws MfNotSupportedException if obj is not correct type for this instance.

Example

stud1 := new Student()
stud1.Id := "RT34TTTSV"
stud1.Name := "Frank Smith"
stud1.Age := 21
stud1.HomeRoom := "English 101"

stud2 := new Student()
stud2.Id := "WRT556SV"
stud2.Name := "Sue Smith"
stud2.Age := 20
stud2.HomeRoom := "French 102"

stud3 := new Student()
stud3.Id := "GTUFF7SV"
stud3.Name := "Bob Smith"
stud3.Age := 22
stud3.HomeRoom := "Math 201"

mfGl := new MfGenericList(Student)

mfGl.Add(stud1)
mfGl.Add(stud2)
mfGl.Add(stud3)

MsgBox, 64, Student Count, % MfString.Format("There are currently {0} Students", mfGl.Count)

for i, st in mfGl
{
   st.EnrollmentYear := A_Year
}
MsgBox % mfGl.Item[0].EnrollmentYear

mfI := new MfInteger(24)
; Next line results in MfNotSupportedException only Student object can be added
mfGl.Add(mfI)

ExitApp

Class Student extends MfObject
{
   m_Id := ""
   m_Name := ""
   m_Age := 0
   m_HomeRoom := ""
   m_EnrollmentYear := 0

   Id[]
   {
       get {
           return this.m_Id
       }
       set {
           this.m_Id := MfString.GetValue(value)
           return this.m_Id
       }
   }

   Name[]
   {
       get {
           return this.m_Name
       }
       set {
           this.m_Name := MfString.GetValue(value)
           return this.m_Name
       }
   }

   Age[]
   {
       get {
           return this.m_Age
       }
       set {
           this.m_Age := MfInteger.GetValue(value, 0)
           return this.m_Age
       }
   }

   HomeRoom[]
   {
       get {
           return this.m_HomeRoom
       }
       set {
           this.m_HomeRoom := MfString.GetValue(value)
           return this.m_HomeRoom
       }
   }

   EnrollmentYear[]
   {
       get {
           return this.m_EnrollmentYear
       }
       set {
           this.m_EnrollmentYear := MfInteger.GetValue(value, 0)
           return this.m_EnrollmentYear
       }
   }

  ; Override ToString()
  ToString()
  {
       ; throw an error if called as static method
       this.VerifyIsInstance(this, A_LineFile, A_LineNumber, A_ThisFunc)
       return MfString.Format("ID:'{0}', Name:'{1}', Age:'{2}'", this.Id, this.Name, this.Age)
  }
}