Data

Gets the Data Dictionary Value for extra MfParams Options

OutputVar := instance.Data

Value

MfDictionary instance

Gets

Data Dictionary as MfDictionary

Remarks

Data Property can be use to store extra information to pass to methods. Data is also used but method such as MfInteger.Parse().
See Also: MfDictionary

Example

; Example MfParams constructor
p := new MfParams("Hello World")  ; Creates new instance of Params and add String object containing "Hello World"
strObj := p.Item[0] ; strObj now contains an instance of String object
MsgBox % strObj.Value ; displays Hello World
MsgBox % p.ToString() ; Displays MfString

; Example using Primitives
intObj := new MfInteger(10)
strObj := new MfString("Hello World")
chrObj := new MfChar("%")
p := new MfParams(intObj, strObj, chrObj)
MsgBox % p.ToString() ; Displays MfInteger,MfString,MfChar
result := MyFunc(p)

/* result contains
* Integer:10
* String:Hello World
* Char:%
*/


; Example Using Add...
p := new MfParams()
p.AddInteger(10)
p.AddString("Hello World")
p.AddChar("%")
MsgBox % p.ToString() ; Displays MfInteger,MsString,MfChar
result := MyFunc(p)

/* result contains
* Integer:10
* String:Hello World
* Char:%
*/


; example passing in objects
myInt := new MfInteger(10)
myStr := new MfString("Hello World")
myChar := new MfChar("%")
result := MyFunc(myInt, myStr, myChar)

/* result contains
* Integer:10
* String:Hello World
* Char:%
*/


; Example using Data
; this example passes MfParams into MfInteger.Parse method with
; Data Key of ReturnAsObject. This cause MfInteger.Parse to return is value
; as an instance of MfInteger rather then the default of a var containing integer.
pStr := "33"
Parms := new MfParams()
Parms.AddString(pStr)
Parms.Data.Add("ReturnAsObject", true)
; parse will return an instance of MfInteger rather than a var integer
; because Parms.Data.Add("ReturnAsObject", true)
int := MfInteger.Parse(Parms)
MsgBox % int.Value

; Also the results of our MyFunc will return an object of MfString
; because Parms.Data.Add("ReturnAsObject", true)
result := MyFunc(Parms)
MsgBox % result.Value ; displays 33

; Example constructor using MfParams static Primitive generators
; Create a new instance of MfParams
; add Integer, String, Char in the constructor
p := new MfParams(MfParams.I(10), MfParams.S("Hello World"), MfParams.C("%"))
MsgBox % p.ToString() ; Displays: MfInteger,MfString,MfChar
result := MyFunc(p)

/* result contains
* Integer:10
* String:Hello World
* Char:%
*/


; Example AddRange using MfParams static Primitive generators
p := new MfParams() ; create a new instance of MfParams
p.AddRange(MfParams.I(10), MfParams.S("Hello World"), MfParams.C("%"))
MsgBox % p.ToString() ; Displays MfInteger,MfString,MfChar
result := MyFunc(p)

/* result contains
* Integer:10
* String:Hello World
* Char:%
*/

ExitApp

; Example function
MyFunc(args*) {
   ; check to see if the first arg is in instance of MfPrams and use if it is
   ; args is 1 base index
   if (MfObject.IsObjInstance(args[1], MfParams))
   {
       p := args[1] ; arg 1 is a MfParams object so we will use it
   } else {
       ; Mfparams was not passed in so we will create an instance and add all the args
       p := new MfParams()
       for index, arg in args
       {
           p.Add(arg)
       }
   }
   ; this method only takes 1 to 3 arguments so we will check and throw an error if wrong number of args
   if ((p.Count < 1) || (p.Count > 3)) {
       e := new MfNotSupportedException(MfEnvironment.Instance.GetResourceString("NotSupportedException_MethodOverload"))
       e.SetProp(A_LineFile, A_LineFile, A_ThisFunc)
       throw e
   }
   strParams := p.ToString()
   retval := "unknown"
   if (strParams = "MfString") {
       str := p.GetValue(0) ; get the first item in the params
       retval := str
   } else if (strParams = "MfString,MfInteger") {
       str := p.GetValue(0) ; get the first item in the params
       int := p.GetValue(1) ; get the second item in the params
       retval := "String:" . str . " Integer:" . int
   } else if (strParams = "MfString,MfString") {
       strObjA := p.Item[0] ; get the first object which is a String Object
       strObjA := p.Item[1] ; get the second object which is a String Object
       retval := MfString.Format("StringA:{0}`nStringB:{1}", strObjA.Value, strObjB.Value)
   } else if (strParams = "MfString,MfChar") {
       str := p.GetValue(0) ; get the first item in the params
       strCh := p.GetValue(1) ; get the second item in the params
       retval := MfString.Format("String:{0}`nChar:{1}", str, strCh)
   } else if (strParams = "MfInteger,MfString,MfChar") {
       retval := MfString.Format("Integer:{0}`nString:{1}`nChar:{2}", p.Item[0].Value, p.Item[1].Value, p.Item[2].Value)
   }
   ; optionally return different value using Data Property
   if (p.Data.Contains("ReturnAsObject") && (p.Data.Item["ReturnAsObject"] = true)) {
       return new MfString(retval) ; return a new instance of MfString
   } else {
       return retval
   }
}