Append()
Appends value to instance.
OutputVar := instance.Append(chars)
OutputVar := instance.Append(chars, startIndex, charCount)
OutputVar := instance.Append(char, repeatCount)
OutputVar := instance.Append(value)
OutputVar := instance.Append(value, startIndex, count)
Appends the string representation of the Unicode characters in a specified list to this instance.
chars
Instance of MfCharList to append.
A reference to this instance after the append operation has completed.
Throws MfArgumentOutOfRangeException if enlarging the value of this instance would exceed MaxCapacity.
This method appends all the characters in the specified MfCharList to the current instance in the same order as they appear in value. If value is null, no changes are made.
The Append(chars) method modifies the existing instance of this class; it does not return a new class instance. Because of this, you can call a method or property on the existing reference and you do not have to assign the return value to a StringBuilder object, as the following example illustrates.
lst := new MfCharList()
lst.AddString("aeiou")
sb := new MfText.StringBuilder()
sb.Append("The characters in the array: ").Append(lst)
MsgBox % sb.ToString()
/*
The characters in the array: aeiou
*/
Appends the string representation of a specified sublist of Unicode characters to this instance.
chars
Instance of MfCharList to append.
startIndex
The starting position in chars.
Can var integer or any type that matches IsInteger.
charCount
The number of characters to append.
Can var integer or any type that matches IsInteger.
A reference to this instance after the append operation has completed.
Throws MfArgumentNullException if chars is null or chars.Count is 0 and startIndex or charCount is not equal to zero.
Throws MfArgumentOutOfRangeException if charCount is less than zero.
- or -
startIndex is less than zero.
- or -
startIndex + charCount is greater than the length of value.
- or -
Enlarging the value of this instance would exceed MaxCapacity.
This method appends the specified range of characters in value to the current instance. If value is null and startIndex and charCount are both zero, no changes are made.
The Append(chars, startIndex, charCount) method modifies the existing instance of this class; it does not return a new class instance. Because of this, you can call a method or property on the existing reference and you do not have to assign the return value to a StringBuilder object, as the following example illustrates.
lst := new MfCharList()
lst.AddString("abcde")
startPosition := lst.IndexOf("a")
endPosition := lst.IndexOf("c")
sb := new MfText.StringBuilder()
if (startPosition >= 0 && endPosition >= 0)
{
sb.Append("The list from positions ").Append(startPosition)
.Append(" to ").Append(endPosition).Append(" contains ")
.Append(lst, startPosition, endPosition + 1).Append(".")
}
MsgBox % sb.ToString()
/*
The list from positions 0 to 2 contains abc.
*/
Appends a specified number of copies of the string representation of a Unicode character to this instance.
char
The character to append.
Can be var, instance of MfChar or Instance of MfString.
Only the first char will be used if var or MfString has more then one char.
repeatCount
The number of times to append value.
Can var integer or any type that matches IsInteger.
A reference to this instance after the append operation has completed.
Throws MfArgumentOutOfRangeException repeatCount is less than zero or enlarging the value of this instance would exceed MaxCapacity.
Throws MfOutOfMemoryException Out of memory.
The Append(char, repeatCount) method modifies the existing instance of this class; it does not return a new class instance. Because of this, you can call a method or property on the existing reference and you do not have to assign the return value to a StringBuilder object, as the following example illustrates.
sb := new MfText.StringBuilder()
flt := new MfFloat(1589.1965,,,"0.4")
sb.Append("*", 5)
.AppendFormat("{0}{1:0.2f}", MfNumberFormatInfo.InvariantInfo.CurrencySymbol, flt.Value)
.Append("*", 5)
MsgBox % sb.ToString() ; *****$1589.20*****
Appends a copy of the specified string var or object to this instance.
value
Value to append to current instance.
Can be var number or string or any object that derives from MfObject.
A reference to this instance after the append operation has completed.
Throws MfArgumentOutOfRangeException if enlarging the value of this instance would exceed MaxCapacity.
The Append(value) method modifies the existing instance of this class; it does not return a new class instance. Because of this, you can call a method or property on the existing reference and you do not have to assign the return value to a StringBuilder object.
When value is an object derived from MfObject it will be added to the current instance by calling the objects ToString() method. Eg: sb.Append(new MfInt16(26)) equals sb.Append(new MfInt16(26).ToString())
flt := new MfFloat(1589.1965)
sb := new MfText.StringBuilder()
sb.Append(flt)
MsgBox % sb.ToString() ; 1589.1965
sb := new MfText.StringBuilder()
sb.Append("Hello World").Append(". Nice to See You!")
MsgBox % sb.ToString() ; Hello World. Nice to See You!
sb := new MfText.StringBuilder()
sb.Append(5).Append(2 + 2).Append(".").Append(3 * 21)
MsgBox % sb.ToString() ; 54.63
sb := new MfText.StringBuilder()
sb.Append(new MfSByte(-124))
MsgBox % sb.ToString() ; -124
sb := new MfText.StringBuilder()
sb.Append(new MfInt64(MfInt64.MinValue))
MsgBox % sb.ToString() ; -9223372036854775808
sb := new MfText.StringBuilder()
sb.Append(new MfUInt64(MfUInt64.MaxValue))
MsgBox % sb.ToString() ; 18446744073709551615
sb := new MfText.StringBuilder()
sb.Append(MfUInt64.MaxValue)
MsgBox % sb.ToString() ; 18446744073709551615
sb := new MfText.StringBuilder()
sb.Append(new MfChar("Z"))
MsgBox % sb.ToString() ; Z
sb := new MfText.StringBuilder()
ex := new MfFormatException("This is a format Exception")
ex.SetProp(A_LineFile, A_LineNumber, "My Special Script")
sb.Append(ex)
MsgBox % sb.ToString()
/*
MfFormatException: This is a format Exception
Source:My Special Script
Line:21
File:D:\Users\user\Documents\AutoHotkey\Scripts\Sample.ahk
*/
Appends a copy of the specified substring to this instance.
value
Value to append to current instance.
Can be var number or string or instance of MfString.
startIndex
The starting position of the substring within value.
Can var integer or any type that matches IsInteger.
count
The number of characters in value to append.
Can var integer or any type that matches IsInteger.
A reference to this instance after the append operation has completed.
Throws MfArgumentOutOfRangeException if count is less than zero.
- or -
startIndex is less than zero.
- or -
startIndex + count is greater than the length of value.
- or -
Enlarging the value of this instance would exceed MaxCapacity.
This method appends the specified range of characters in value to the current instance. If value is null and startIndex and count are both zero, no changes are made.
The Append(value, startIndex, count) method modifies the existing instance of this class; it does not return a new class instance. Because of this, you can call a method or property on the existing reference and you do not have to assign the return value to a StringBuilder object, as the following example illustrates.
str := new MfString("First;George Washington;1789;1797", true)
sb := new MfText.StringBuilder()
index := 0
length := str.IndexOf(";", index)
sb.Append(str, index, length).Append(" President of the United States: ")
index += length + 1
length := str.IndexOf(";", index) - index
sb.Append(str, index, length).Append(", from ")
index += length + 1
length := str.IndexOf(";", index) - index
sb.Append(str, index, length).Append(" to ")
index += length + 1
sb.Append(str, index, str.Length - index)
MsgBox % sb.ToString() ; First President of the United States: George Washington, from 1789 to 1797